; $Id: opan_readtextgroup.pro,v 1.2 2005/01/31 17:29:03 dimeo Exp $
;###############################################################################
;
; NAME:
;  OPAN_READTEXTGROUP
;
; PURPOSE:
;  Reads in grouped text data.
;
; CATEGORY:
;  DAVE, Data Analysis, PAN, curve fitting
;
; AUTHOR:
;   Robert M. Dimeo, Ph.D.
;   NIST Center for Neutron Research
;   100 Bureau Drive
;   Gaithersburg, MD 20899
;   Phone: (301) 975-8135
;   E-mail: robert.dimeo@nist.gov
;   http://www.ncnr.nist.gov/staff/dimeo
;
; LICENSE:
;  The software in this file is written by an employee of
;  National Institute of Standards and Technology
;  as part of the DAVE software project.
;
;  The DAVE software package is not subject to copyright protection
;  and is in the public domain. It should be considered as an
;  experimental neutron scattering data reduction, visualization, and
;  analysis system. As such, the authors assume no responsibility
;  whatsoever for its use, and make no guarantees, expressed or
;  implied, about its quality, reliability, or any other
;  characteristic. The use of certain trade names or commercial
;  products does not imply any endorsement of a particular product,
;  nor does it imply that the named product is necessarily the best
;  product for the stated purpose. We would appreciate acknowledgment
;  if the DAVE software is used of if the code in this file is
;  included in another product.
;
;###############################################################################
function opan_readTextGroup,filename
if n_params() eq 0 then return,(-1)

dummy = ''
openr,lun,filename,/get_lun
; Read in the number of channels
repeat begin
  readf,lun,dummy
  colPos = strpos(dummy,'#')
endrep until colPos eq (-1)

nchan = fix(dummy)
x = fltarr(nchan)

; Read in the number of groups
repeat begin
  readf,lun,dummy
  colPos = strpos(dummy,'#')
endrep until colPos eq (-1)
ngroups = fix(dummy)
y = fltarr(ngroups)
z = fltarr(nchan,ngroups)
zerr = fltarr(nchan,ngroups)

repeat begin
  readf,lun,dummy
  colPos = strpos(dummy,'#')
endrep until colPos eq (-1)

; Read in the xvalues
x[0] = float(dummy)
for j = 1,nchan-1 do begin
  readf,lun,dummy
  x[j] = float(dummy)
endfor

; Read in the yvalues
repeat begin
  readf,lun,dummy
  colPos = strpos(dummy,'#')
endrep until colPos eq (-1)
y[0] = float(dummy)
for j = 1,ngroups-1 do begin
  readf,lun,dummy
  y[j] = float(dummy)
endfor

xval = 0.0 & yval = 0.0

for i = 0,ngroups-1 do begin
  repeat begin
    readf,lun,dummy
    colPos = strpos(dummy,'#')
  endrep until colPos eq (-1)
  vals = strsplit(dummy,' ',/extract)
  z[0,i] = float(vals[0])
  zerr[0,i] = float(vals[1])
  for j = 1,nchan-1 do begin
    readf,lun,xval,yval
    z[j,i] = float(xval)
    zerr[j,i] = float(yval)
  endfor
endfor

free_lun,lun

d = {x:x,y:y,z:z,zerr:zerr, $
     xlabel:'x', $
     ylabel:'y', $
     zlabel:'z'}

return,d
end