; $Id: eisfparmentry.pro,v 1.3 2005/02/09 14:53:32 dimeo Exp $
;###############################################################################
;
; NAME:
;  EISFPARMENTRY
;
; PURPOSE:
;  UI for user to enter parameters that define the EISF (elastic, inelastic, and
;  quasielastic components--if applicable).
;
; CATEGORY:
;  DAVE, Data Analysis, PAN, curve fitting
;
; AUTHOR:
;   Robert M. Dimeo, Ph.D.
;   NIST Center for Neutron Research
;   100 Bureau Drive
;   Gaithersburg, MD 20899
;   Phone: (301) 975-8135
;   E-mail: robert.dimeo@nist.gov
;   http://www.ncnr.nist.gov/staff/dimeo
;
; LICENSE:
;  The software in this file is written by an employee of
;  National Institute of Standards and Technology
;  as part of the DAVE software project.
;
;  The DAVE software package is not subject to copyright protection
;  and is in the public domain. It should be considered as an
;  experimental neutron scattering data reduction, visualization, and
;  analysis system. As such, the authors assume no responsibility
;  whatsoever for its use, and make no guarantees, expressed or
;  implied, about its quality, reliability, or any other
;  characteristic. The use of certain trade names or commercial
;  products does not imply any endorsement of a particular product,
;  nor does it imply that the named product is necessarily the best
;  product for the stated purpose. We would appreciate acknowledgment
;  if the DAVE software is used of if the code in this file is
;  included in another product.
;
;###############################################################################
pro eisf_event,event

widget_control,event.top,get_uvalue = pState
widget_control,event.id,get_value = val

widget_control,(*pState).elField,get_value = elText
elText = elText[0]
widget_control,(*pState).qeField,get_value = qeText
qeText = qeText[0]
el = opan_selectgroups(elText)
qe = opan_selectgroups(qeText)

case val[0] of
'ACCEPT':	begin
			  (*pState).canceled = 0
			  *(*pState).qePtr = qe
			  *(*pState).elPtr = el
			end
'CANCEL':	begin
			  (*pState).canceled = 1
			end
else:
endcase
widget_control,event.top,/destroy

return
end
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
function eisfparmentry,group_leader = group_leader,canceled = canceled
if n_elements(group_leader) eq 0 then begin
  tlb = widget_base(/col,/tlb_frame_attr,title = 'EISF parameter entry')
endif else begin
  tlb = widget_base(/col,/tlb_frame_attr,title = 'EISF parameter entry', $
        group_leader = group_leader)
endelse
elField = cw_field(tlb,/row,title = 'Elastic parameters (e.g. 1)',value = '1')
qeField = cw_field(tlb,/row,title = 'Quasielastic parameters (e.g. 1,2)', $
          value = '2,3')
rowBase = widget_base(tlb,/row)
void = widget_button(rowBase,value = 'ACCEPT')
void = widget_button(rowBase,value = 'CANCEL')

widget_control,tlb,/realize

state = {elPtr:ptr_new(/allocate_heap), $
         qePtr:ptr_new(/allocate_heap), $
         elField:elField, $
         qeField:qeField, $
         canceled:1 }

pState = ptr_new(state,/no_copy)
widget_control,tlb,set_uvalue = pState
xmanager,'eisfparmentry',tlb,event_handler = 'eisf_event'

eisf = {el:(*(*pState).elPtr), $
        qe:(*(*pState).qePtr), $
        canceled:(*pState).canceled}

ptr_free,(*pState).elPtr,(*pState).qePtr
ptr_free,pState
return,eisf
end
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;