; $Id: dcs_str_shorthand.pro,v 1.3 2005/02/14 17:50:14 azuah Exp $
; Written by J.R.D. Copley.
;************************************************************************************************
;###############################################################################
;
; LICENSE:
;  The software in this file is written by an employee of 
;  National Institute of Standards and Technology 
;  as part of the DAVE software project.
;
;  The DAVE software package is not subject to copyright protection
;  and is in the public domain. It should be considered as an
;  experimental neutron scattering data reduction, visualization, and
;  analysis system. As such, the authors assume no responsibility
;  whatsoever for its use, and make no guarantees, expressed or
;  implied, about its quality, reliability, or any other
;  characteristic. The use of certain trade names or commercial
;  products does not imply any endorsement of a particular product,
;  nor does it imply that the named product is necessarily the best
;  product for the stated purpose. We would appreciate acknowledgment
;  if the DAVE software is used or if the code in this file is
;  included in another product.
;
;###############################################################################
function dcs_str_shorthand,instr
;************************************************************************************************
;
compile_opt strictarr
;
; This routine takes a comma-delimited list of detectors and converts it into a more compact form.
; For example if instr='1,2,3,7,8,9,10,144,145,146,456' the function returns '1-3,7-10,144-146,456'
;
if (instr eq '') then return,instr
ints=fix(strsplit(instr,',',/extract))
nints=n_elements(ints)
kstrt=0
n=1
outstr=''
for k=1,nints-1 do begin
	if (ints[k] eq ints[kstrt]+n) then n=n+1 else begin
		outstr=outstr+strcompress(ints[kstrt],/remove_all)
		kend=k-1
		if (kstrt ne kend) then outstr=outstr+'-'+strcompress(ints[kend],/remove_all)
		outstr=outstr+','
		kstrt=k
		n=1
	endelse
endfor
outstr=outstr+strcompress(ints[kstrt],/remove_all)
kend=nints-1
if (kstrt ne kend) then outstr=outstr+'-'+strcompress(ints[kend],/remove_all)
return,outstr
end
